ANSYS之LINK180施加预应力及生死单元应用 - 小众知识

ANSYS之LINK180施加预应力及生死单元应用

2021-04-22 08:06:41 苏内容
  标签: ANSYS/LINK180
阅读:4825

【要点:解决LINK180施加预应力方法(初应变、降温)、生死单元中的应用,以及仅拉/仅压设置问题】

高版本中不再推荐LINK10单元,采用LINK180或CABLE280(另文解说)模拟索结构。LINK180单元预应力的模拟可采用降温法和初应变法两种,降温法简单而形象;初应变法在低版本中也较为简单,但高版本采用INISTATE命令就比较复杂(主要还是ANSYS的HELP写的不够好)。

索的张拉应力或张拉力是“结果”,即在张拉过程中,随着索力的不断增加,结构同时在发生变形,当达到索的张拉力后,结构也变形完毕,此时索中的力就是“张拉力”,因此“索张拉力是结果”。换句话说,计算分析时,施加一个略大的温度或初应变,求解完成后,查看索力是否等于张拉力?否则就要重新“试错“计算(一般几次即可),直到计算后索力等于张拉力。

一、预应力施加方法

1、降温法:降温法需要设置材料的线胀系数,然后根据张拉力计算索的应变,该应变除线胀系数即为降温数值。即应变=张拉力/(索面积×索弹性模量),降温数值=应变/线胀系数。然后用BFE命令给索单元施加降温值。对于实际结构,试错计算次数很少,因为实际结构刚度往往很大,一束索力不会造成结构很大变形,基本上施加降温的索力与张拉力相差无几。

2、INISTATE施加初应变方法

与低版本实常数定义初应变不同,INISTATE只能在/SOLU层执行,在/PREP7定义无效。

INISTATE,Action,Val1,Val2,Val3,Val4,Val5,Val6,Val7,Val8,Val9

其中Action有多个,如SET、DEFINE、WRITE、READ、LIST、DELETE等,主要使用前两个。

“INISTATE,SET,Val1,Val2”时,Val1可取CSYS、DTYP、MA、NODE、DATA等,Val2则对应不同的值。

“INISTATE,DEFINE,ID,EINT,KLAYER,PARMINT,Cxx,Cyy,Czz,Cxy,Cyz,Cxz”时,又有很多选项,可查看HELP解释。以几个小例子说明初应变的使用方法,可以看出功能很强,但也较复杂。

!为整个模型施加常应变

!x向为0.1,y向为-0.01,z向为-0.01

inistate,set,dtyp,epel

inistate,defi,,,,,0.1,-0.01,-0.01

!给单元8施加x向常应变0.01

!特别注意是给“单元号为8的单元”

inistate,set,dtyp,epel$inistate,defi,8,,,,0.01

!给单元2的积分点3施加x向应变0.01

inistate,set,dtyp,epel$inistate,defi,2,3,,,0.01

!给所选择的所有梁单元的第2删格施加x向应变1e-6

inistate,set,dtyp,epel$inistate,defi,,,2,,1E-6

!给所有材料号为3的单元施加x向应变1e-3

inistate,set,dtyp,epel$inistate,set,mat,3

inistate,defi,,,,,1E-3

二、如图1所示的结构,几何和材料参数详见命令流中。先完成两个悬臂梁并在A点施加30kN向下的力;第二步在AB之间挂索并张拉50kN(即张拉完成后索张力为50kN)。梁采用BEAM189模拟,索采用LINK180模拟;分为两个荷载步,打开大变形效应开关,通过试错初始应变使得索张力为50kN。

先按图1(b)直接一步计算最终结构,此时索张力50kN为最终索力(类似成结构索力或成桥索力),经试算初应变或温度的增大系数为1.6589。在此初应变和降温下,计算完成后的索力正好达到50kN。

FINISH$/CLEAR$/PREP7!MM-N-MPA

D=400 !梁直径

LBEAM=3000 !梁跨度

HCAB=4000 !索长度

ACAB=140 !索面积

FCAB=50E3 !索张拉力

EMOD=2.0E5 !材料弹性模量

PLX=1E-5 !线胀系数

!索初应变(系数1.6589为试算得到)

ISCAB=FCAB/(ACAB*EMOD)*1.6589

TT=ISCAB/PLX !降温值

P=30E3

ET,1,BEAM189

ET,2,LINK180

R,1

SECTYPE,1,BEAM,CSOLID

SECDATA,D/2

SECTYPE,2,LINK

SECDATA,ACAB

MP,EX,1,EMOD

MP,PRXY,1,0.3

MP,EX,2,EMOD

MP,PRXY,2,0.3

MP,ALPX,2,PLX

K,1

K,2,LBEAM

K,3,LBEAM,-HCAB

K,4,0,-HCAB

L,1,2,10

L,3,2,5

L,3,4,10

LSEL,S,,,1,3

LATT,1,,1,,,,1

LSEL,S,,,2

LATT,2,,2,,,,2

LSEL,ALL

LMESH,ALL

DK,1,ALL

DK,4,ALL

/SOLU

NLGEOM,ON

OUTRES,ALL,ALL

NSUBST,10

TIME,1

FK,2,FY,-P

!加载方法控制,kz=1为初应变,否则为降温法

KZ=1

*IF,KZ,EQ,1,THEN

!定义初应变,材料2全部施加ISCAB应变

INISTATE,SET,DTYP,EPEL

INISTATE,SET,MAT,2

INISTATE,DEFINE,,,,,ISCAB

*ELSE

ESEL,S,TYPE,,2

BFE,ALL,TEMP,,-TT

ESEL,ALL

*ENDIF

SOLVE

/POST1

SET,1,LAST

PLNSOL,U,Y

!轴力50000N

ESEL,S,TYPE,,2!

ETABLE,FORL,SMISC,1

PRETAB,FORL

如果不能确认上述结果是否正确,可以采用图1(c)无索模型计算,验证位移是否正确。

三、生死单元分两个荷载步完成,命令流如下:

FINISH$/CLEAR$/PREP7

D=400$LBEAM=3000$HCAB=4000$ACAB=140

FCAB=50E3$EMOD=2.0E5$PLX=1E-5

ISCAB=FCAB/(ACAB*EMOD)*1.6589!

TT=ISCAB/PLX$P=30E3

ET,1,BEAM189$ET,2,LINK180$R,1

SECTYPE,1,BEAM,CSOLID$SECDATA,D/2

SECTYPE,2,LINK$SECDATA,ACAB

MP,EX,1,EMOD$MP,PRXY,1,0.3

MP,EX,2,EMOD$MP,PRXY,2,0.3

MP,ALPX,2,PLX!

K,1$K,2,LBEAM

K,3,LBEAM,-HCAB$K,4,0,-HCAB

L,1,2,10$L,2,3,5$L,3,4,10

LSEL,S,,,1,3$LATT,1,,1,,,,1

LSEL,S,,,2$LATT,2,,2,,,,2

LSEL,ALL$LMESH,ALL

DK,1,ALL$DK,4,ALL

/SOLU$NLGEOM,ON

NSUBST,10$OUTRES,ALL,ALL

!加载控制,kz=1为初应变,否则为降温法

KZ=1.0

*IF,KZ,EQ,1,THEN!

INISTATE,SET,DTYP,EPEL!

INISTATE,SET,MAT,2!

INISTATE,DEFINE,,,,,ISCAB!

*ELSE!

ESEL,S,TYPE,,2!!

BFE,ALL,TEMP,,-TT!

ESEL,ALL!

*ENDIF!

!杀死索单元

TIME,1$FK,2,FY,-P

ESEL,S,TYPE,,2$EKILL,ALL

ESEL,ALL$SOLVE

!激活索单元

TIME,2

ESEL,S,TYPE,,2$EALIVE,ALL

ESEL,ALL$SOLVE!

/POST1$SET,1,LAST$PLNSOL,U,Y

ESEL,S,TYPE,,2$ETABLE,FORL1,SMISC,1

PRETAB,FORL1

1604470180(1).jpg

(1)生死单元分两步的计算结果与二中的完全一样。

(2)降温法和初应变法都可采用,但降温法更容易实现,INISTATE定义初应变法复杂些。

(3)如果采用低版本的LINK10结果相同,命令流方式还可继续使用不再推荐的单元。

(4)LINK180的仅压/仅拉设置,采用命令“SECCONTROL,ADDMAS,TENSKEY”控制,其中TENSKEY=1为仅拉,TENSKEY=-1为仅压。改变了采用实常数控制方式或KEYOPT控制。


扩展阅读
相关阅读
© CopyRight 2010-2021, PREDREAM.ORG, Inc.All Rights Reserved. 京ICP备13045924号-1